# Pastebin NU7fM9A2
{ lib
, makeWrapper
, pkgs
#, runCommand, wrapBintoolsWith, wrapCCWith
, buildAndroidndk, androidndk, targetAndroidndkPkgs
}:

let
  # Mapping from a platform to information needed to unpack NDK stuff for that
  # platform.
  #
  # N.B. The Android NDK uses slightly different LLVM-style platform triples
  # than we do. We don't just use theirs because ours are less ambiguous and
  # some builds need that clarity.
  ndkInfoFun = { config, ... }: {
    x86_64-apple-darwin = {
      double = "darwin-x86_64";
    };
    x86_64-unknown-linux-gnu = {
      double = "linux-x86_64";
    };
    i686-unknown-linux-android = {
      triple = "i686-linux-android";
      arch = "x86";
      toolchain = "x86";
      gccVer = "4.9";
    };
    x86_64-unknown-linux-android = {
      triple = "x86_64-linux-android";
      arch = "x86_64";
      toolchain = "x86_64";
      gccVer = "4.9";
    };
    armv7a-unknown-linux-androideabi = {
      arch = "arm";
      triple = "arm-linux-androideabi";
      toolchain = "arm-linux-androideabi";
      gccVer = "4.9";
    };
    aarch64-unknown-linux-android = {
      arch = "arm64";
      triple = "aarch64-linux-android";
      toolchain = "aarch64-linux-android";
      gccVer = "4.9";
    };
  }.${config} or
    (throw "Android NDK doesn't support ${config}, as far as we know");

  hostInfo = ndkInfoFun pkgs.stdenv.hostPlatform;
  targetInfo = ndkInfoFun pkgs.stdenv.targetPlatform;

  sdkVer = pkgs.stdenv.targetPlatform.sdkVer;
  prefix = lib.optionalString (pkgs.stdenv.targetPlatform != pkgs.stdenv.hostPlatform) (pkgs.stdenv.targetPlatform.config + "-");
in

rec {
  # Misc tools
  binaries = pkgs.runCommand "ndk-toolchain-binutils" {
    pname = "ndk-toolchain-binutils";
    inherit (androidndk) version;
    isClang = true; # clang based cc, but bintools ld
    nativeBuildInputs = [ makeWrapper pkgs.python ];

    propagatedBuildInputs = [ androidndk ];
  } ''
    mkdir -p $out/
    ${androidndk}/libexec/android-sdk/ndk-bundle/build/tools/make-standalone-toolchain.sh --arch=${targetInfo.arch} --install-dir=$out/toolchain --platform=${sdkVer}
    mkdir -p $out/lib
    cp $out/toolchain/sysroot/usr/lib/${targetInfo.triple}/*.so $out/lib/
    cp $out/toolchain/sysroot/usr/lib/${targetInfo.triple}/*.a $out/lib/
    chmod +w $out/lib/*
    cp $out/toolchain/sysroot/usr/lib/${targetInfo.triple}/${sdkVer}/*.so $out/lib/
    cp $out/toolchain/sysroot/usr/lib/${targetInfo.triple}/${sdkVer}/*.a $out/lib/
    cp $out/toolchain/sysroot/usr/lib/${targetInfo.triple}/${sdkVer}/*.o $out/lib/

    ln -s $out/toolchain/bin $out/bin
    patchShebangs $out/bin/

    for f in $out/toolchain/${targetInfo.triple}/bin/*; do
      ln -s $f $out/bin/$(basename $f)
    done


  '';

  binutils = pkgs.wrapBintoolsWith {
    bintools = binaries;
    libc = targetAndroidndkPkgs.libraries;
  };

  clang = pkgs.wrapCCWith {
    cc = binaries // {
      # for packages expecting libcompiler-rt, etc. to come from here (pkgs.stdenv.cc.cc.lib)
      lib = targetAndroidndkPkgs.libraries;
    };
    bintools = binutils;
    libc = targetAndroidndkPkgs.libraries;
    extraBuildCommands = ''
      echo "NIX_SUPPORT": $out/nix-support
      echo "-D__ANDROID_API__=${pkgs.stdenv.targetPlatform.sdkVer}" >> $out/nix-support/cc-cflags
      echo "-target ${targetInfo.toolchain}" >> $out/nix-support/cc-cflags
      echo "-resource-dir=$(echo ${androidndk}/libexec/android-sdk/ndk-bundle/toolchains/llvm/prebuilt/${hostInfo.double}/lib*/clang/*)" >> $out/nix-support/cc-cflags
      echo "--gcc-toolchain=${androidndk}/libexec/android-sdk/ndk-bundle/toolchains/${targetInfo.toolchain}-${targetInfo.gccVer}/prebuilt/${hostInfo.double}" >> $out/nix-support/cc-cflags
      echo "-L${binaries}/lib" >> $out/nix-support/cc-cflags
    '';
  };

  # Bionic lib C and other libraries.
  #
  # We use androidndk from the previous stage, else we waste time or get cycles
  # cross-compiling packages to wrap incorrectly wrap binaries we don't include
  # anyways.
  libraries = pkgs.runCommand "bionic-prebuilt" {} ''
    mkdir -p $out/lib
    cp ${buildAndroidndk}/libexec/android-sdk/ndk-bundle/toolchains/llvm/prebuilt/linux-x86_64/sysroot/usr/lib/${targetInfo.triple}/${sdkVer}/* $out/lib
  '';
}