# Pastebin BlAsXVfU
with (import (
  fetchTarball {
    url = https://github.com/nixos/nixpkgs-channels/archive/c4196cca9acd1c51f62baf10fcbe34373e330bb3.tar.gz;
    sha256 = "0jsisiw8yckq96r5rgdmkrl3a7y9vg9ivpw12h11m8w6rxsfn5m5";
  }
) { });
let
  gems = bundlerEnv {
    ruby = ruby_2_6;
    name = "test-digest-sha3";
    gemdir = ./.;
    gemConfig = defaultGemConfig // {
      pg_query = attrs:
        let
          libpg_query = fetchurl {
            url = "https://codeload.github.com/lfittl/libpg_query/tar.gz/10-1.0.1";
            sha256 = "0m5jv134hgw2vcfkqlnw80fr3wmrdvgrvk1ndcx9s44bzi5nsp47";
          };
        in {
        dontBuild = false;
        preBuild = ''
          sed -i ext/pg_query/extconf.rb -e "3a \
            require 'fileutils'; \
            FileUtils.cp('${libpg_query}', 'libpg_query.tar.gz') \
          "
          cat ext/pg_query/extconf.rb
        '';
      };
    };
  };

  env = if builtins.pathExists ./gemset.nix then [
    gems.wrappedRuby
    (lowPrio gems)
  ] else
    builtins.trace "to get your gems, please run bundix -l" [ ];
in mkShell { buildInputs = [ bundix ] ++ env; }